Las Reliquias de Tolti Aph
An interactive fiction by Graham Nelson (2005) - the Inform 7 source text
Contents
Previous
Next
Complete text
The Cámara Archivo is a room. "Un sótano, pero difícilmente el sótano de una posada; esta debía de ser una tapadera. Aquí estaban almacenados el conocimiento de ciertos hechizos de un poder o importancia particular, aquellos que sus poseedores no querían confiar a los simples pergaminos. Hace mucho tiempo los féretros ocupaban ambos lados de esta habitación, pero hoy en día la mayoría están rotos y vacíos, sus ocupantes convertidos en polvo; en algunos casos muy recientemente, debido tu caida.
El último ataúd que queda de una pieza está sellado mágicamente. Es de una madera semitransparente y contiene una inmóvil figura."
Some ataúdes rotos are scenery in the Cámara Archivo. The description is "Sus sellos están rotos y el contenido no es más que polvo." Effect of casting remendar at the ataúdes rotos: record outcome "pero no puede restaurar las múltiples capas de magia antigua que los mantenían intactos"; rule succeeds. The ataúdes rotos are madera.
Some gafas de infravisión are in the Cámara Archivo. "Desplazadas quizás por tu caida, un par de gafas de infravisión está tiradas en el suelo de piedra, la calavera que las llevaba ahora no es más que polvo." The description of the gafas is "No observas nada especial en las gafas de infravisión. No, en serio, nunca les has encontrado nada de especial. Pero ok, de hecho a los usuarios de magia-del-lado-oscuro les gusta llevarlas por la ciudad con una pose de soy-demasiado-guai-para-que-me-de-la-luz-solar." The gafas are wearable. After looking when in darkness and the player is wearing the gafas de infravisión, say "Realmente es un mito que las gafas de infravisión permiten ver en la oscuridad. En realidad te permiten ver la luz refractándose sobre superficies mágicas." The gafas are metal. The gafas are female.
The último ataúd is transparent closed scenery in the Cámara Archivo. It contains a inmóvil figura. The figura is a woman. The figura knows invocar elemental. The description of the inmóvil figura is "Su cara es de rasgos afilados, sus cejas rectas de una forma que sólo habías visto en las estatuas. Pero ella respira. Muy lentamente, pero respira." Instead of opening the ataúd, say "Está sellado con una magia muy poderosa, protejiendo la vida en su interior." Instead of entering the ataúd, say "Subirte al ataúd no te ayudará a estar más cerca del techo, y si te refieres a entrar, está cerrado a cal y canto; aparte de las consideraciones sobre la decencia humana." The último ataúd is madera.
Understand "ultimo ataúd" or "ataúd" as the último ataúd.
Instead of going up in the Cámara Archivo, say "Parece que no hay manera humana de trepar hasta el agujero cuadrado del techo abovedado de este sótano." Instead of going nowhere from the Cámara Archivo, say "Exploras cada esquina del sótano, con la esperanza de encontrar una salida. Pero está muy bien asegurado contra las plagas, inhundaciones, ladrones y cosas por el estilo."
The agujero cuadrado en el techo abovedado is scenery thing in the Cámara Archivo. The description of the agujero cuadrado is "A través del agujero cuadrado en el techo, el sol de la tarde te tienta: esa etérela, sencilla perfección que sólo es apreciada por aquellos que la ven desde la celda en su prisión." Understand "trampilla" as the agujero cuadrado. The agujero cuadrado is aire.
The Prison Visit is a scene. The Prison Visit begins when the player is in the Cámara Archivo for the ninth turn. The Prison Visit ends when the player is not in the Cámara Archivo.
Table of Prison Visit Noises Off
| noise message |
| "Justo cuando comienzas a pensar que el estar prisionero aquí abajo no es vida para un usuario de magia joven con tanto que ofrecer (o por ejemplo, tanto que recibir), crees que podrías haber oido un ligero sonido proveniente desde arriba." |
| "No, no debe de haber sido nada." |
| "Ese ligero segundo sonido también debe de haber sido nada." |
| "Quizás todas esas columnas se están reagrupando por si mismas." |
| "Comienzas a conjurar una imagen mental del salvador ideal, pisando suavemente por los escombros de ahí arriba, y apunto de caer sobre ti." |
| "Un salvador. Sin lugar a dudas. Veamos. Bonita sonrisa, bronceado saludable quizás, un punto de brillante excitación en sus ojos, veinte metros de cuerda y un garfio de escala enrollados sobre su hombro. Un poco de temor reverencial por los usuarios de magia, puestos a pedir. Sí, todo eso vendría primorosamente bien en estos momentos." |
| "Espera... parece que el ruido aumenta. Parecen pisadas que se acercan, de hecho." |
| "¿Es tu imaginación? ¿O eso ha sonado como una respiración?" |
| "Parándose a pensarlo, la idea de este encuentro inminente te hace estar algo nervioso. Juegas con tu pelo, miras tus uñas, inquieto." |
| "Dentro de un minuto, y será como esos poemas de aventura romántica. Viajareis por el bosque salvaje juntos." |
| "Eso es, estaréis juntos en el bosque a menos que no ocurra nada." |
| "Oh, ¿cuándo va a aparecer esa sonrisa divina por el agujero del techo?" |
| "Ah, esto es una metáfora de la vida misma." |
| "Tum te tum. Tum tum te-tum." |
[NT: Lo siguiente no funciona... estaría sin testear así que añadiré un verbo básico para que sí funcione:]
Understand the command "grita" as something new.
Understand "grita" as screaming. Screaming is an action applying to nothing. Report screaming: say "No hay necesidad de armar tal alboroto."
[Lo siguiente es lo que no funcionaba muy allá.]
Screaming is making a rumpus. Answering is making a rumpus. Singing is making a rumpus. Asking someone for something is making a rumpus. Knocking on the agujero is making a rumpus. Instead of making a rumpus during the Prison Visit, say "No importa cuán alto llames, el sonido parece morir ante los fúnebres muros de esta cripta."
Every turn during the Prison Visit:
repeat through the Table of Prison Visit Noises Off
begin;
say "[noise message entry][paragraph break]";
blank out the whole row;
stop;
end repeat.[1]
Effect of casting telaraña at the agujero cuadrado:
if Prison Visit is happening, record outcome "pero aunque una plausible telaraña se mantiene en el agujero por un momento, obviamente no es tan espectacular como para llamar la atención de la persona misteriosa de ahí arriba";
otherwise record outcome "pero aunque una plausible telaraña se mantiene en el agujero por un momento, no dura mucho, y de todas formas eso no significa que se descuelgue una hebra hasta tu nivel para poder escalar";
rule succeeds.
Effect of casting misil mágico at the agujero cuadrado:
if Prison Visit is happening
begin;
record outcome "y un espectacular misil de fuegos artificiales es lanzado al cielo del atardecer. Debe de haber llamado la atención de alguien, seguro. Y tu corazón se acelera cuando el extremo de una cuerda de unos quince metros llega hasta tus pies, y una vaga figura te lanza un grito amortiguado de bienvenida desde arriba, y subes al gancho de escalada para ser elevado arriba, arriba, por encima de los viejos ataúdes y por encima del borde de la trampilla hasta...
Oh, bueno, ¿no es [italic type]exactamente[roman type] como la vida misma? Saltas hacia atrás. Al igual que tu benefactor. La trampilla se cierra coléricamente, engullendo la cuerda como si fuese un espagueti";
record event the rescued from the archive rule;
otherwise;
record outcome "y un espectacular misil de fuego es lanzado al cielo del atardecer. Debe de haber llamado la atención de alguien, ¿seguro? Pero, ¿en una ciudad abandonada desde hace siglos, quien va ha haber?";
end if;
rule succeeds.
Instead of listening during Prison Visit, say "El problema es que, cuanto más te concentras en escuchar, más y más escuchas los latidos de tu propio corazón y de tu respiración."
Glog el Troll is a troll de las cavernas.[2]
This is the rescued from the archive rule:
now the trampilla is closed;
now the trampilla is locked;
move Glog to the Patio de la Vieja Escuela;
now Glog is surprised;
move the player to the Patio de la Vieja Escuela.